EAPI=8

VALA_MIN_API_VERSION="0.56"
VALA_USE_DEPEND="vapigen"

inherit git-r3 meson vala xdg

DESCRIPTION="Another.im desktop client"
HOMEPAGE="https://another.im"
EGIT_REPO_URI="https://dev.narayana.im/anotherim/anotherim-desktop.git"
EGIT_BRANCH="dev"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="+http-files +ice +omemo openpgp +rtp +notification-sound"

DEPEND="
	$(vala_depend)

	dev-db/sqlcipher:=
	dev-libs/glib:2
	dev-libs/icu:=
	dev-libs/libgee:0.8
	x11-libs/gdk-pixbuf:2
	gui-libs/gtk:4
	gui-libs/libadwaita:1

	http-files? ( net-libs/libsoup:3.0 )

	ice? (
		dev-libs/libgcrypt:=
		net-libs/libsrtp:2
		net-libs/libnice
		net-libs/gnutls
	)

	omemo? (
		dev-libs/libgcrypt:=
		net-libs/libsrtp:2
		media-gfx/qrencode:=
		net-libs/libomemo-c:=
	)

	openpgp? ( app-crypt/gpgme:= )

	rtp? (
		dev-libs/libgcrypt:=
		net-libs/libsrtp:2
		media-libs/gstreamer:1.0
		media-libs/gst-plugins-base:1.0
		media-libs/webrtc-audio-processing:=
	)

	notification-sound? ( media-libs/libcanberra )
"
RDEPEND="${DEPEND}"
BDEPEND="
	dev-build/meson
	dev-build/ninja
	sys-devel/gettext
	virtual/pkgconfig
"

src_prepare() {
	default
	vala_setup
}

src_configure() {
	local emesonargs=(
		-Dplugin-http-files=$(usex http-files enabled disabled)
		-Dplugin-ice=$(usex ice enabled disabled)
		-Dplugin-omemo=$(usex omemo enabled disabled)
		-Dplugin-openpgp=$(usex openpgp enabled disabled)
		-Dplugin-rtp=$(usex rtp enabled disabled)
		-Dplugin-notification-sound=$(usex notification-sound enabled disabled)
		-Dset-install-rpath=false
	)

	meson_src_configure
}